100 REM FILEMAKER: FONT FILE CREATOR FOR CLOCKWISE
101 :
105 REM WRITTEN BY JOHN KROUT
106 :
110 REM COPYRIGHT 1987 BY JOHN KROUT
111 :
115 REM MAY BE COPIED AND DISTRIBUTED FOR FREE BUT NOT SOLD OR MODIFIED
116 :
189 :
190 REM COPY THE C64 ROM FONT INTO RAM
191 :
200 PRINT CHR$( 147 ) CHR$( 14 ) : POKE 56, 19 : POKE 55, 255 : CLR
205 POKE 56334, PEEK( 56334 ) AND 254
210 PRINT"MOVING CHARACTER SHAPES TO [210][193][205] ..." : PRINT
215 POKE 1, PEEK( 1 ) AND 251 : A=2047 : B=5120 : C=53248 + 2048
220 FOR I=0 TO A : POKE I + B, PEEK( I+C ) : NEXT
230 POKE 1, PEEK( 1 ) OR 4 : POKE 56334, PEEK( 56334 ) OR 1
239 :
300 PRINT "CREATING SHAPE TRANSLATION TABLE ..." : PRINT
305 BB=5120 + 2048 : FOR P=0 TO 255 : PB=P + BB : POKE PB, P OR 128
310 K2=1 : FOR J=0 TO 6 : K=64 / K2 : POKE PB, PEEK( PB ) AND ( 255-K )
315 IF P AND K2 THEN POKE PB, PEEK( PB )OR K
320 K2=K2 * 2 : NEXT : NEXT
349 :
350 PRINT CHR$(147)
352 PRINT "TIME TO SAVE THE FONTFILE ON DISK."
354 PRINT "PUT YOUR CLOCKWISE DISK IN THE DRIVE"
356 PRINT "AND THEN TAP THE [210][197][212][213][210][206] KEY."
358 GET A$ : IF A$="" GOTO 358
360 PRINT CHR$(147) : PRINT
365 PRINT "POKE43, 0 : POKE44, 20 : POKE 45, 0 : POKE46, 29" : PRINT : PRINT
370 PRINT "SAVE"+CHR$(34)+"FONTFILE"+CHR$(34)+",8" : PRINT : PRINT : PRINT
375 PRINT "POKE 43, 1 : POKE 44, 8 : POKE 45," PEEK(45) ": POKE 46," PEEK(46)
380 PRINT CHR$(19);
385 POKE 631, 13 : POKE 632, 13 : POKE 633, 13 : POKE 198, 3